# Convert Currency in Number to Words (Indian Rupees) - Version 2

This VBA script converts currency in number to words. It is based on Indian Rupees and Indian Numbers system. This script can be used as module in Microsoft Office programs such as MS Excel, MS Word, MS Access

To know how to use this code, please check our previous article

Convert Currency in Number to Words (Indian Rupees)

Below code adds 'and' joining word before 1st, 10th and 100th place wherever necessary.

Function ConvertCurrencyToEnglish(ByVal MyNumber)
' Edited by Karthikeyan [email protected]
Dim Temp
Dim Rupees, Paise
Dim DecimalPlace, Count

ReDim Place(9) As String
Place(2) = " Thousand "
Place(3) = " lakh "
Place(4) = " Crore "

' Convert MyNumber to a string, trimming extra spaces.
MyNumber = Trim(Str(MyNumber))

' Find decimal place.
DecimalPlace = InStr(MyNumber, ".")

' If we find decimal place...
If DecimalPlace > 0 Then
' Convert Paise
Temp = Left(Mid(MyNumber, DecimalPlace + 1) & "00", 2)
' Hi! Note the above line Mid function it gives right portion
' after the decimal point
'if only . and no numbers such as 789. accures, mid returns nothing
' to avoid error we added 00
' Left function gives only left portion of the string with specified places here 2

Paise = ConvertTens(Temp)

' Strip off paise from remainder to convert.
MyNumber = Trim(Left(MyNumber, DecimalPlace - 1))
End If

Count = 1
If MyNumber <> "" Then

' Convert last 3 digits of MyNumber to Indian Rupees.
Temp = ConvertHundreds(Right(MyNumber, 3), Paise, MyNumber)

If Temp <> "" Then Rupees = Temp & Place(Count) & Rupees

If Len(MyNumber) > 3 Then
' Remove last 3 converted digits from MyNumber.
MyNumber = Left(MyNumber, Len(MyNumber) - 3)
Else
MyNumber = ""
End If

End If

' convert last two digits to of mynumber
Count = 2

Do While MyNumber <> ""
Temp = ConvertTens(Right("0" & MyNumber, 2))

If Temp <> "" Then Rupees = Temp & Place(Count) & Rupees
If Len(MyNumber) > 2 Then
' Remove last 2 converted digits from MyNumber.
MyNumber = Left(MyNumber, Len(MyNumber) - 2)

Else
MyNumber = ""
End If
Count = Count + 1

Loop

' Clean up rupees.
Select Case Rupees
Case ""
Rupees = ""
Case "One"
Rupees = "Rupee One"
Case Else
Rupees = "Rupees " & Rupees
End Select

' Clean up paise.
Select Case Paise
Case ""
Paise = ""
Case "One"
Paise = "One Paise"
Case Else
Paise = Paise & " Paise"
End Select

If Rupees = "" Then
ConvertCurrencyToEnglish = Paise & " Only"
ElseIf Paise = "" Then
ConvertCurrencyToEnglish = Rupees & " Only"
Else
ConvertCurrencyToEnglish = Rupees & " and " & Paise & " Only"
End If

End Function

Private Function ConvertDigit(ByVal MyDigit)
Select Case Val(MyDigit)
Case 1: ConvertDigit = "One"
Case 2: ConvertDigit = "Two"
Case 3: ConvertDigit = "Three"
Case 4: ConvertDigit = "Four"
Case 5: ConvertDigit = "Five"
Case 6: ConvertDigit = "Six"
Case 7: ConvertDigit = "Seven"
Case 8: ConvertDigit = "Eight"
Case 9: ConvertDigit = "Nine"
Case Else: ConvertDigit = ""
End Select

End Function

Private Function ConvertHundreds(ByVal MyNumber, ByVal Paise, ByVal OriginalNumber)
Dim Result As String

Result10or1 = ""
Result100 = ""

' Exit if there is nothing to convert.
If Val(MyNumber) = 0 Then Exit Function

' Append leading zeros to number.
MyNumber = Right("000" & MyNumber, 3)

' Do we have a hundreds place digit to convert?
If Left(MyNumber, 1) <> "0" Then
Result100 = ConvertDigit(Left(MyNumber, 1)) & " Hundred "
End If

' Do we have a tens place digit to convert?
If Mid(MyNumber, 2, 1) <> "0" Then
Result10or1 = ConvertTens(Mid(MyNumber, 2))
Else
' If not, then convert the ones place digit.
Result10or1 = ConvertDigit(Mid(MyNumber, 3))
End If

' if 1st & 10th places are zero, place 'and' before hundreds
' else place before 10th place

'if paise not exists add 100
If (Paise <> "") Then
Result = Result100 + Result10or1
Else
If (Result100 <> "") Then
If (Result10or1 <> "") Then
Result = Result100 + "and " + Result10or1
Else
If (Len(OriginalNumber) > 3) Then
Result = "and " + Result100
Else
Result = Result100
End If
End If

Else
If (Result10or1 <> "") Then
If (Len(OriginalNumber) > 2) Then
Result = "and " + Result10or1
Else
Result = Result10or1
End If
End If

End If

End If

ConvertHundreds = Trim(Result)
End Function

Private Function ConvertTens(ByVal MyTens)
Dim Result As String

' Is value between 10 and 19?
If Val(Left(MyTens, 1)) = 1 Then
Select Case Val(MyTens)
Case 10: Result = "Ten"
Case 11: Result = "Eleven"
Case 12: Result = "Twelve"
Case 13: Result = "Thirteen"
Case 14: Result = "Fourteen"
Case 15: Result = "Fifteen"
Case 16: Result = "Sixteen"
Case 17: Result = "Seventeen"
Case 18: Result = "Eighteen"
Case 19: Result = "Nineteen"
Case Else
End Select
Else
' .. otherwise it's between 20 and 99.
Select Case Val(Left(MyTens, 1))
Case 2: Result = "Twenty "
Case 3: Result = "Thirty "
Case 4: Result = "Forty "
Case 5: Result = "Fifty "
Case 6: Result = "Sixty "
Case 7: Result = "Seventy "
Case 8: Result = "Eighty "
Case 9: Result = "Ninety "
Case Else
End Select

' Convert ones place digit.
Result = Result & ConvertDigit(Right(MyTens, 1))
End If

ConvertTens = Trim(Result)
End Function

### Sample output

 1.23457e+08 Rupees Twelve Crore Thirty Four lakh Fifty Six Thousand Seven Hundred Eighty Nine and Fifty Paise Only 1.23457e+07 Rupees One Crore Twenty Three lakh Forty Five Thousand Six Hundred and Seventy Eight Only 1.23457e+06 Rupees Twelve lakh Thirty Four Thousand Five Hundred and Sixty Seven Only 123456 Rupees One lakh Twenty Three Thousand Four Hundred and Fifty Six Only 123456 Rupees One lakh Twenty Three Thousand Four Hundred and Fifty Six Only 12345 Rupees Twelve Thousand Three Hundred and Forty Five Only 1234 Rupees One Thousand Two Hundred and Thirty Four Only 123 Rupees One Hundred and Twenty Three Only 12 Rupees Twelve Only 1 Rupee One Only 10 Rupees Ten Only 100 Rupees One Hundred Only 1000 Rupees One Thousand  Only 10000 Rupees Ten Thousand  Only 100000 Rupees One lakh  Only 1e+06 Rupees Ten lakh  Only 1e+07 Rupees One Crore  Only 1e+08 Rupees Ten Crore  Only 1.23457e+08 Rupees Twelve Crore Thirty Four lakh Fifty Six Thousand Seven Hundred and Eighty Only 1.23457e+08 Rupees Twelve Crore Thirty Four lakh Fifty Six Thousand and Seven Hundred Only 1.23456e+08 Rupees Twelve Crore Thirty Four lakh Fifty Six Thousand  Only 1.2345e+08 Rupees Twelve Crore Thirty Four lakh Fifty Thousand  Only 1.234e+08 Rupees Twelve Crore Thirty Four lakh  Only 1.23e+08 Rupees Twelve Crore Thirty lakh  Only 1.2e+08 Rupees Twelve Crore  Only 1e+08 Rupees Ten Crore  Only 1.23457e+08 Rupees Twelve Crore Thirty Four lakh Fifty Six Thousand Seven Hundred and Eight Only 1.23456e+08 Rupees Twelve Crore Thirty Four lakh Fifty Six Thousand and Seventy Eight Only
Category
Tags

Karthikeyan

Jul 29, 2020 - 21:02

Sure, I will work on it and update you.

Rakesh

Jul 29, 2020 - 17:53

can you please share that changes with me also...??

rakesh

Jul 29, 2020 - 11:01

Hi karthik... I must say, really a very nice and useful formula. Thnks
I have a question here, there is no category for the numbers above 99,99,99,999/-, Can you please make something in this like Rupees Hundred Crores, do you get my point..??? Otherwise this one is perfect ....

Karthikeyan

Jul 25, 2020 - 12:09

In reply to by Harish Chandra Singh

It should not come like that, let me know the sample number.
Yes, you can round off the paise. use excel formula
example = ConvertCurrencyToEnglish(ROUND(A1));

Harish Chandra Singh

Jul 24, 2020 - 18:56

Hi Karthikeyan
Thanks for the code,
I have 1 doubt, why is the paise always coming 1 paise less all the time.
Is there a possibility to round off the paise..

stella

May 01, 2020 - 16:18

Thanks for the code karthik,I have tried to edit the code but every time it had some issue,code is working so well..thank you so much for your quick response.all the Best.